-= Gametoast.com =-

Teancum wrote: ... and munge.bat in data_XXX/_BUILD/Sound

Hidden/Spoiler:

@REM WARNING: enabledelayedexpansion means ! is a special character,
@REM which means it isn't available for use as the mungeapp recursive
@REM wildcard character. Use the alternate $ instead.
@setlocal enabledelayedexpansion
@set MUNGE_ROOT_DIR=..\..
@if not "%1"=="" set MUNGE_PLATFORM=%1
@if %MUNGE_PLATFORM%x==x set MUNGE_PLATFORM=PC
@if "%MUNGE_BIN_DIR%"=="" (
@set MUNGE_BIN_DIR=%CD%\%MUNGE_ROOT_DIR%\..\ToolsFL\Bin
@set PATH=%CD%\..\..\..\ToolsFL\Bin;%PATH%
@echo MUNGE_BIN_DIR=!MUNGE_BIN_DIR!
)
@rem convert to lower case
@if %MUNGE_PLATFORM%==PC set MUNGE_PLATFORM=pc
@if %MUNGE_PLATFORM%==XBOX set MUNGE_PLATFORM=xbox
@if %MUNGE_PLATFORM%==PS2 set MUNGE_PLATFORM=ps2

@if /i %MUNGE_PLATFORM%==pc @set BANKOPT=-template -stub "c:\windows\media\chord.wav"

@set LOCAL_MUNGE_LOG="%CD%\%MUNGE_PLATFORM%_MungeLog.txt"
@if "%MUNGE_LOG%"=="" (
@set MUNGE_LOG=%LOCAL_MUNGE_LOG%
@if exist %LOCAL_MUNGE_LOG% ( del %LOCAL_MUNGE_LOG% )
)
@rem echo ********************************************************************* >> %MUNGE_LOG%
@rem echo Sound\munge.bat %MUNGE_PLATFORM% >> %MUNGE_LOG%
@rem echo MUNGE_BIN_DIR=%MUNGE_BIN_DIR% >> %MUNGE_LOG%
@rem echo ********************************************************************* >> %MUNGE_LOG%

@cd ..\..

@if not exist _LVL_%MUNGE_PLATFORM% mkdir _LVL_%MUNGE_PLATFORM%
@if not exist _LVL_%MUNGE_PLATFORM%\Sound mkdir _LVL_%MUNGE_PLATFORM%\Sound

@if /i %MUNGE_PLATFORM%==pc @set BANKOPT=-template

@call soundmunge.bat %MUNGE_PLATFORM%
@if %SOUNDCLEANLVL%x==1x @del /S /Q _BUILD\sound\*.lvl & @call soundmunge.bat %MUNGE_PLATFORM%

@if /i not "%SOUNDLVL%"=="" (
@for %%A in (%SOUNDLVL%) do @if /i "%%A"=="global" @goto buildglobalbank
@goto skipglobalbank
)
:buildglobalbank
@rem Build a global sound bank...
@set BANKLIST=
@for /R %%A in (*.sfx) do @set BANKLIST=!BANKLIST! %%A
@for /R %%A in (*.asfx) do @set BANKLIST=!BANKLIST! %%A
@if %SOUNDLOG%x==1x ( @set SOUNDOPT=-verbose & @set SOUNDLOGOUT=%LOGDIR%\SoundBankLog.txt ) else ( @set SOUNDOPT= & @set SOUNDLOGOUT=NUL )

@if not %MUNGE_PLATFORM%==pc goto skipglobalbank
@echo Munging common.bnk, this could take a while...
@soundflmunge -platform %MUNGE_PLATFORM% -banklistinput %BANKLIST% -bankoutput _LVL_%MUNGE_PLATFORM%\Sound\common.bnk -checkdate -resample -compact nowarning -checkid noabort -relativepath %SOUNDOPT% 2>>%MUNGE_LOG% 1>>%SOUNDLOGOUT%

:skipglobalbank

@cd _BUILD\Sound

@REM If the munge log was created locally and has anything in it, view it
@if not %MUNGE_LOG%x==%LOCAL_MUNGE_LOG%x goto skip_mungelog
@set FILE_CONTENTS_TEST=
@if exist %MUNGE_LOG% for /f %%i in (%MUNGE_LOG:"=%) do @set FILE_CONTENTS_TEST=%%i
@if not "%FILE_CONTENTS_TEST%"=="" ( Notepad.exe %MUNGE_LOG% ) else ( if exist %MUNGE_LOG% (del %MUNGE_LOG%) )

:skip_mungelog

@rem convert to upper case
@if %MUNGE_PLATFORM%==pc set MUNGE_PLATFORM=PC
@if %MUNGE_PLATFORM%==xbox set MUNGE_PLATFORM=XBOX
@if %MUNGE_PLATFORM%==ps2 set MUNGE_PLATFORM=PS2

@endlocal

• I was not able to ever build a complete sound.lvl. I always had to only include any new sounds, and munge that into another sound.lvl. Then, in the LUA, I had to "leech" off of another sound.lvl by saying: readfile sound/yavcw.lvl then readfile baacw.lvl underneath that. It had to be an ammendment not a replacement. Not sure if that's the issue (or if it even was just a local issue to me). It's what I had to do to get battle arena (baa) to work
• I'm assuming by the lvls building that they have the contents of the sounds in them. If the filesize seems reasonable for including all the sound files for a level, you could even go further to open it in a hex editor to see what's there (although you probably won't gain much from doing that).
• If the lvl is built, and it include sound effects, or at least configs for them (you can see via hex editor), the next step is to check the lua line. I know you probably did it right, but 1 digit makes everything fail...

@set MUNGE_DIR=MUNGED\%MUNGE_PLATFORM%

RepSharpshooter wrote:EDIT: I concur that:

Code: Select all

@set MUNGE_DIR=MUNGED\%MUNGE_PLATFORM%

Is missing under the red text, perhaps you should try inserting that first of all and see what happens.

Aman/Pinguin wrote:You're missing @set MUNGE_DIR=MUNGED\%MUNGE_PLATFORM% under your red marked part. I will look if I can find more errors...

RepSharpshooter wrote:I concur

RepSharpshooter wrote:

RepSharpshooter wrote:I concur

I agree (with you). I checked as well just to make sure it should be there.

Teancum wrote:I've ran it with it there and with it not. The file built both times, but not sounds were in-game. I'm working with psych0fred on the issue. I think it goes a lot deeper than one line in a batch file.