Sound Problems

Kingpin · Post by **Kingpin** » Mon Mar 17, 2014 7:42 pm

I hate to ask this, as I usually try and figure stuff like this out myself, but yeah.

So I have been trying to get custom ambient sounds working on my hero assault map. First, I tried using Mav's tutorial on munging through BF1; however, this did not munge correctly, as nothing on my BFBuildier works. So, I tried doing it in BFII. I followed the tutorial, but when I munge, nothing is where it should be. Yes, I used Mav's fixed soundmunge.bats and such. Would anyone who has done this before be willing to help me out and munge my sounds for me?
Thank you so much!

Post by **AceMastermind** » Tue Mar 18, 2014 3:26 am

Can you create a map with either of the tools? If you can create a map successfully then you can munge sounds, music etc. What tutorials did you follow? Where did you put the modified bat files etc?
If you're asking again for someone to do it for you instead of solving the problem then this thread will be removed since there is already a pending request.

LukeBenVader1 · Post by **LukeBenVader1** » Tue Mar 18, 2014 7:06 am

Did you follow Rend's tutorial on how to get the sound munged in-game:
http://www.gametoast.com/viewtopic.php?f=27&t=4750

Kingpin · Post by **Kingpin** » Tue Mar 18, 2014 5:49 pm

http://www.gametoast.com/viewtopic.php? ... &sk=t&sd=a
http://www.gametoast.com/viewtopic.php?f=27&t=18595
http://www.gametoast.com/viewtopic.php?f=27&t=9541
And that other one you showed me. None of them worked.
I managed to create a world, that works fine. Say I go to my dataXXX/sounds and set up a new world for sounds, then I munge, it does not appear as the xxx.lvl in my _LVLPC/Sound folder. Like I said, nothing munges correctly. I tried Mav's fixed .bats, but they still did not fix it. I want to do this myself, I just highly doubt that I can get anything working, considering the time I have put into this already.

Anakin · Post by **Anakin** » Wed Mar 19, 2014 9:41 am

data_XX\
soundmunge.bat

Hidden/Spoiler:

[code]@if %1x==x goto noplatform

@set MUNGE_PLATFORM=%1

@set MUNGE_DIR=MUNGED\%MUNGE_PLATFORM%

@rem EDIT THE LINE BELOW TO POINT TO YOUR BF2 INTSALL PATH

@set BF2_SOUNDPATH="C:\Users\Carsten\AppData\Local\VirtualStore\Program Files (x86)\LucasArts\Star Wars Battlefront II\"

@rem Munge global, shell and side specific sound data

@rem Munge world specific sound data

@call soundmungedir _BUILD\sound\worlds\rcm\%MUNGE_DIR% sound\worlds\rcm sound\worlds\rcm\%MUNGE_PLATFORM% %MUNGE_PLATFORM% _BUILD _LVL_%MUNGE_PLATFORM%\sound _BUILD\sound rcm

@rem EDIT THE TWO LINES BELOW TO POINT TO YOUR MOD BY REPLACING SND WITH YOUR WORLD ABBREVIATION

xcopy _LVL_%MUNGE_PLATFORM%\sound\*  %BF2_SOUNDPATH%GameData\addon\RCM\data\_LVL_PC\Sound\ /Y

@goto exit

:noplatform

@echo Platform must be specified as the first argument

:exit[/code]

soundmungedir.bat

Hidden/Spoiler:

[code]@rem Save the starting directory

@for /F %%A in ('cd') do @set STARTDIR=%%A

@if %1x==x goto nomungedir

@if %2x==x goto nosourcedir

@if %3x==x goto nooverridedir

@if %4x==x goto noplatform

@if %5x==x goto nomungelogdir

@if %6x==x goto noleveldir

@if %7x==x goto nolevelsrcdir

@if %8x==x goto nolevelfile

@rem Setup directories

@set MUNGEDIR=%STARTDIR%\%1

@set SOURCEDIR=%STARTDIR%\%2

@set PLATFORMDIR=%STARTDIR%\%3

@set LOGDIR=%STARTDIR%\%5

@set LEVELDIR=%STARTDIR%\%6

@set LEVELFILEREQ=%8%.req

@set LEVELFILELVL=%MUNGEDIR%\%8%.lvl

@set CHECKDATE=-checkdate

@set CHECKID=-checkid

@if %SOUNDNODATECHECK%x==1x @set CHECKDATE=

@rem Build up a list of directories for level pack to search for source files

@Setlocal enabledelayedexpansion 

@set LEVELSRCDIR=

@set PATH="%CD%"\..\ToolsFL\Bin;%PATH%

@rem Should we munge this level ?

@if /i not "%SOUNDLVL%"=="" (

	@for %%A in (%SOUNDLVL%) do @if /i "%%A"=="%8" @goto mungeit

	@goto exit

)

:mungeit

@if "%MUNGE_LOG%"=="" set MUNGE_LOG=%LOGDIR%\%4%_MungeLog.txt

@if not EXIST %SOURCEDIR% (

	@echo Unable to munge %SOURCEDIR% as it doesn't exist! 1>> %MUNGE_LOG%  

	@goto exit 

)

@REM goto nodebug

@echo Current Directory           = %CD%

@echo Sound level filter          = %SOUNDLVL%

@echo Munge output directory      = %MUNGEDIR%

@echo Source directory            = %SOURCEDIR%

@echo Platform override directory = %PLATFORMDIR%

@echo Selected platform           = %4

@echo Munge logs directory        = %LOGDIR%

@echo Level file output directory = %LEVELDIR%

@echo Final req file              = %LEVELFILEREQ%

@echo Output level file           = %LEVELFILELVL%

@echo Additional stream options   = %STREAMOPT%

@REM pause

:nodebug

@if EXIST %MUNGEDIR% goto skipcreatemungedir

@mkdir %MUNGEDIR%

:skipcreatemungedir

@cd %SOURCEDIR%

@rem Munge configuration files

@rem *.snd - sound library

@rem *.mus - dynamic music configuration

@rem *.ffx - foley effects

@rem *.tsr - sound regions

@configmunge -inputfile *.snd *.mus *.ffx *.tsr -platform %4 -sourcedir %PLATFORMDIR% %SOURCEDIR% -outputdir %MUNGEDIR% -hashstrings %CHECKDATE% -continue 2>>%MUNGE_LOG% 

@if %SOUNDLOG%x==1x ( @set SOUNDOPT=-verbose & @set SOUNDLOGOUT=%LOGDIR%\SoundBankLog.txt ) else ( @set SOUNDOPT= & @set SOUNDLOGOUT=NUL )

@rem Munge sound banks

@for /R %%A in (*.sfx) do @echo Munging %%~nA%%~xA & @soundflmunge -platform %4 -banklistinput %%A -bankoutput %MUNGEDIR%\ %CHECKDATE% -resample %CHECKID% noabort %SOUNDOPT% %BANKOPT% 2>>%MUNGE_LOG% 1>>%SOUNDLOGOUT%

@for /R %%A in (*.asfx) do @echo Munging %%~nA%%~xA & @soundflmunge -platform %4 -banklistinput %%A -bankoutput %MUNGEDIR%\ %CHECKDATE% -resample -checkid noabort %SOUNDOPT% 2>>%MUNGE_LOG% 1>>%SOUNDLOGOUT%

@rem Munge streams

@rem Localization

@rem Setup the extension of localized stream files (if it's english we'll just use the default extension)

@set LANGVERSION=

@rem @for /F %%A in (%MUNGE_LANGVERSION%) do @set LANGVERSION=%%~A

@set LANGVERSION=%MUNGE_LANGVERSION%

@if /i %LANGVERSION%x==Englishx ( @set LOCALIZEEXT= ) else ( @set LOCALIZEEXT=stm_%LANGVERSION% )

@rem make the directory for language-specific stuff if it doesn't exist - H8 h8 h8!

@if EXIST %MUNGEDIR%\%LANGVERSION% goto skipcreatelangdir

@echo Creating dir %MUNGEDIR%\%LANGVERSION%\

@mkdir %MUNGEDIR%\%LANGVERSION%

:skipcreatelangdir

@rem Munge localized stream files

@if /i not %MUNGESTREAMS%x==0x @if /i not %LANGVERSION%x==Englishx @for /R %%A in (*.%LOCALIZEEXT%) do @echo Munging %%~nA%%~xA to %MUNGEDIR%\%LANGVERSION%\ & soundflmunge -platform %4 -banklistinput %%A -bankoutput %MUNGEDIR%\%LANGVERSION%\%%~nA.str -stream %CHECKDATE% -resample %CHECKID% noabort %SOUNDOPT% %STREAMOPT% 2>>%MUNGE_LOG% 1>>%SOUNDLOGOUT%

@set MUNGE2SUBSTREAMS=0

@if /i %4==XBOX @set MUNGE2SUBSTREAMS=1

@if /i %4==PC   @set MUNGE2SUBSTREAMS=1

@rem Build up a list of 1 substream streams to munge, 

@rem Filtering the localize streams and if on xbox 4 channel streams 

@set MUNGESUBSTREAM1=

@if /i not %MUNGESTREAMS%x==0x @for /R %%A in (*.stm) do @if /i %%~xA==.stm ( @if not EXIST %%~dA%%~pA%%~nA.%LOCALIZEEXT% ( @if /i %MUNGE2SUBSTREAMS%==1 ( @if not EXIST %%~dA%%~pA%%~nA.st4 @set MUNGESUBSTREAM1=!MUNGESUBSTREAM1! %%A ) else ( @set MUNGESUBSTREAM1=!MUNGESUBSTREAM1! %%A ) ) )

@rem Munge 1 substream streams

@if /i not %MUNGESTREAMS%x==0x @for %%A in (%MUNGESUBSTREAM1%) do @echo Munging %%~nA%%~xA & soundflmunge -platform %4 -banklistinput %%A -bankoutput %MUNGEDIR%\ -stream %CHECKDATE% -resample %CHECKID% noabort %SOUNDOPT% %STREAMOPT% 2>>%MUNGE_LOG% 1>>%SOUNDLOGOUT%

@rem Munge 2 substream streams

@if /i not %MUNGESTREAMS%x==0x @if %MUNGE2SUBSTREAMS%==1 @for /R %%A in (*.st4) do @echo Munging %%~nA%%~xA & soundflmunge -platform %4 -banklistinput %%A -bankoutput %MUNGEDIR%\ -stream %CHECKDATE% -resample %CHECKID% noabort %SOUNDOPT% %STREAMOPT% -substream 2 2>>%MUNGE_LOG% 1>>%SOUNDLOGOUT%

@rem Build level files

@if EXIST %LEVELDIR% goto skipcreateleveldir

@mkdir %LEVELDIR%

:skipcreateleveldir

@if %SOUNDNOLVL%x==1x @goto exit

@rem build up a list of include directories for levelpack

@rem language overrides first!

@if %LANGVERSION%x==x goto skiplang

@for /F %%A in ('dir /AD /B %STARTDIR%\%7') do @set LANGSRCDIR=!LANGSRCDIR! %STARTDIR%\%7\%%A\MUNGED\%4\%LANGVERSION%

@for /F %%A in ('dir /AD /B %STARTDIR%\%7\Worlds') do @set LANGSRCDIR=!LANGSRCDIR! %STARTDIR%\%7\Worlds\%%A\MUNGED\%4\%LANGVERSION%

:skiplang

@for /F %%A in ('dir /AD /B %STARTDIR%\%7') do @set LEVELSRCDIR=!LEVELSRCDIR! %STARTDIR%\%7\%%A\MUNGED\%4

@for /F %%A in ('dir /AD /B %STARTDIR%\%7\Worlds') do @set LEVELSRCDIR=!LEVELSRCDIR! %STARTDIR%\%7\Worlds\%%A\MUNGED\%4

@for /R %%A in (*.req) do @if /i not %%A==%SOURCEDIR%\%LEVELFILEREQ% levelpack -inputfile %%~nA%%~xA -platform %4 -sourcedir %SOURCEDIR% %LANGSRCDIR% %PLATFORMDIR% -inputdir %LEVELSRCDIR% -outputdir %MUNGEDIR% -continue %CHECKDATE%

@if EXIST %LEVELFILEREQ% levelpack -inputfile %LEVELFILEREQ% -platform %4 -sourcedir %SOURCEDIR% %LANGSRCDIR% %PLATFORMDIR% -inputdir %LEVELSRCDIR% -outputdir %LEVELDIR% -continue %CHECKDATE%

@goto exit

:nomungedir

@echo Munge directory must be specified as the first argument

@goto exit

:nosourcedir

@echo Source data directory must be specified as the second argument

@goto exit

:nooverridedir

@echo Platform specific source data directory must be specified as the third argument

@goto exit

:noplatform

@echo Platform must be specified as the fourth argument

@goto exit

:nomungelogdir

@echo Munge log directory must be specified as the fifth argument

@goto exit

:noleveldir

@echo Level output directory must be specified as the sixth argument

@goto exit

:nolevelsrcdir

@echo Level source direct must be specified as the seventh argument

@goto exit

:nolevelfile

@echo Final output level file must be specified as the eighth argument

@goto exit

:exit

@endlocal

@cd %STARTDIR%[/code]

soundmungelevel.bat

Hidden/Spoiler:

[code]@set PLATFORM=%2

@echo Munging %1 for %PLATFORM%

@if %3x==rebuildx @set SOUNDNODATECHECK=1

@if %PLATFORM%x==x @set PLATFORM=PC

cd _BUILD\sound

@if %3x==onlyworldx goto onlyworld

set SOUNDLVL=global

call munge %PLATFORM%

set SOUNDLVL=shell

call munge %PLATFORM%

set SOUNDLVL=cw

call munge %PLATFORM%

set SOUNDLVL=gcw

call munge %PLATFORM%

:onlyworld

set SOUNDLVL=%1

call munge %PLATFORM%

cd ..\..

set SOUNDLVL=

@if %3x==rebuildx @set SOUNDNODATECHECK=

@if /i not %PLATFORM%==xbox goto exit 

xbcp -d -y -t -r -f _lvl_xbox\*.lvl xe:\Battlefront2\Data\_lvl_xbox\

xbcp -d -y -t -r -f _lvl_xbox\*.mvs xe:\Battlefront2\Data\_lvl_xbox\

xbcp -d -y -t _build_xbox\dsstdfx.bin xe:\Battlefront2\Data\

:exit[/code]

data_XXX\_BUILD\Sound\
munge.bat

Hidden/Spoiler:

[code]@REM WARNING: enabledelayedexpansion means ! is a special character,

@REM   which means it isn't available for use as the mungeapp recursive

@REM   wildcard character.  Use the alternate $ instead.

@setlocal enabledelayedexpansion

@set MUNGE_ROOT_DIR=..\..

@if not "%1"=="" set MUNGE_PLATFORM=%1

@if %MUNGE_PLATFORM%x==x set MUNGE_PLATFORM=PC

REM @if "%MUNGE_BIN_DIR%"=="" (

	@set MUNGE_BIN_DIR=%CD%\%MUNGE_ROOT_DIR%\..\ToolsFL\Bin

	@set PATH=%CD%\..\..\..\ToolsFL\Bin;%PATH%

	@echo MUNGE_BIN_DIR=!MUNGE_BIN_DIR!

REM)

@rem convert to lower case

set MUNGE_PLATFORM=pc

@set BANKOPT=-template -stub c:\windows\media\chord.wav

@set MUNGE_DIR=MUNGED\%MUNGE_PLATFORM%

@set LOCAL_MUNGE_LOG="%CD%\%MUNGE_PLATFORM%_MungeLog.txt"

@if "%MUNGE_LOG%"=="" (

	@set MUNGE_LOG=%LOCAL_MUNGE_LOG%

	@if exist %LOCAL_MUNGE_LOG% ( del %LOCAL_MUNGE_LOG% )

)

@rem echo ********************************************************************* >> %MUNGE_LOG%

@rem echo Sound\munge.bat %MUNGE_PLATFORM% >> %MUNGE_LOG%

@rem echo MUNGE_BIN_DIR=%MUNGE_BIN_DIR% >> %MUNGE_LOG%

@rem echo ********************************************************************* >> %MUNGE_LOG%

@cd ..\..

@if not exist _LVL_%MUNGE_PLATFORM% mkdir _LVL_%MUNGE_PLATFORM%

@if not exist _LVL_%MUNGE_PLATFORM%\Sound mkdir _LVL_%MUNGE_PLATFORM%\Sound

@call soundmunge.bat %MUNGE_PLATFORM%

@if %SOUNDCLEANLVL%x==1x @del /S /Q _BUILD\sound\*.lvl & @call soundmunge.bat %MUNGE_PLATFORM%

@if /i not "%SOUNDLVL%"=="" (

	@for %%A in (%SOUNDLVL%) do @if /i "%%A"=="global" @goto buildglobalbank

	@goto skipglobalbank

)

:buildglobalbank

@rem Build a global sound bank...

@set BANKLIST=

@for /R %%A in (*.sfx) do @set BANKLIST=!BANKLIST! %%A

@for /R %%A in (*.asfx) do @set BANKLIST=!BANKLIST! %%A

@if %SOUNDLOG%x==1x ( @set SOUNDOPT=-verbose & @set SOUNDLOGOUT=%LOGDIR%\SoundBankLog.txt ) else ( @set SOUNDOPT= & @set SOUNDLOGOUT=NUL )

@if not %MUNGE_PLATFORM%==pc goto skipglobalbank

@echo Munging common.bnk, this could take a while...

@soundflmunge -platform %MUNGE_PLATFORM% -banklistinput %BANKLIST% -bankoutput _LVL_%MUNGE_PLATFORM%\Sound\common.bnk -checkdate -resample -compact nowarning -checkid noabort -relativepath %SOUNDOPT% 2>>%MUNGE_LOG% 1>>%SOUNDLOGOUT%

:skipglobalbank

@cd _BUILD\Sound

@REM If the munge log was created locally and has anything in it, view it

@if not %MUNGE_LOG%x==%LOCAL_MUNGE_LOG%x goto skip_mungelog

@set FILE_CONTENTS_TEST=

@if exist %MUNGE_LOG% for /f %%i in (%MUNGE_LOG:"=%) do @set FILE_CONTENTS_TEST=%%i

@if not "%FILE_CONTENTS_TEST%"=="" ( Notepad.exe %MUNGE_LOG% ) else ( if exist %MUNGE_LOG% (del %MUNGE_LOG%) )

:skip_mungelog

@rem convert to upper case

@if %MUNGE_PLATFORM%==pc   set MUNGE_PLATFORM=PC

@if %MUNGE_PLATFORM%==xbox set MUNGE_PLATFORM=XBOX

@if %MUNGE_PLATFORM%==ps2  set MUNGE_PLATFORM=PS2

@endlocal

[/code]

This are my bat files. Have a look if yours are the same (They will only work for PC, after i deleted some PS and XBOX things. And all RCM need to be your mod id).

Than make sure you have a folder structure like this:
data_RCM\Sound\worlds\rcm\
rcm.req

Hidden/Spoiler:

[code]

ucft

{

	REQN

	{

		"str"

		"align=2048"

	}

	REQN

	{

		"lvl"

		"comSnd"

	}	

 }

[/code]

than you need a comSnd.req file

Hidden/Spoiler:

[code]ucft

{

	REQN

	{

		"bnk"

		"align=2048"

		"rcm"

	}

	REQN

	{

		"config"

		"commandos"

	}

 }[/code]

this calls a rcm.asfx file

Hidden/Spoiler:

[code]effects\dc17_rifle.wav    -resample xbox 22050 pc 22050

[/code]

I just take this one sound as example. In my file are some more.

and than you need the commandos.snd file (windows calls them au file)

Hidden/Spoiler:

[code]

SoundProperties()

{

    Name("dc17_rifle_fire");

    Group("weapons");

    Inherit("weapon_template");

    SampleList()

    {

        Sample("dc17_rifle", 1.0);

    }

}

[/code]

I know that is not exactly what you are looking for, but this is how the sound mungeing works. This works for me, but i start the soundmunge.bat file via CMD.
"soundmunge.bat PC"

So i also tryed me at the ambiente sounds, and it seams that i could munge them, but i haven't get them ingame yet. So maybe you want to try the sound things first to make sure the munge bats work.

Kingpin · Post by **Kingpin** » Thu Mar 20, 2014 7:13 pm

I tried using those .bats, still, nothing munged in my sound folder.

Anakin · Post by **Anakin** » Fri Mar 21, 2014 6:03 am

Have you started the munge bat via double click, Visual ModTools.exe or cmd?? What is the munge output??

Kingpin · Post by **Kingpin** » Sat Mar 22, 2014 11:18 am

Visual ModTools

Anakin · Post by **Anakin** » Sat Mar 22, 2014 11:43 am

that doesn't work for me. try mungeing it via cmd

Kingpin · Post by **Kingpin** » Sat Mar 22, 2014 12:25 pm

Marth8880 · Post by **Marth8880** » Sat Mar 22, 2014 1:18 pm

Ohhh, he means running the munge.bat files instead of using crappy VisualMunge. So yeah, to do so, just run munge.bat in data_***\_BUILD\Sound\.

Anakin · Post by **Anakin** » Sat Mar 22, 2014 2:29 pm

no just the munge.bat doesn't work. You need to use a cmd console. just press windows+r and type cmd. Than you browse your directory and run the bat this way:

soundmunge.bat PC

you cannot run the bat via double click because you need to tell the bat what you are playing on (PC, PS2, XBOX). that's way you need to type PC behind soundmunge.bat.

Marth8880 · Post by **Marth8880** » Sat Mar 22, 2014 2:48 pm

Running the munge.bat files has worked for me for over the past two years. No clue why it wouldn't work for you, but whatever.

Kingpin · Post by **Kingpin** » Sat Mar 22, 2014 3:03 pm

I tried just running the munge. It says "munging common.bnk, this could take a while...". Then the mungelog comes up, does that mean it is done?

Marth8880 · Post by **Marth8880** » Sat Mar 22, 2014 3:04 pm

Yes. You'll probably have to manually copy over the sound LVL to your addon folder.

Anakin · Post by **Anakin** » Sat Mar 22, 2014 3:12 pm

if he uses the bat's i posted and he changed the directory, the soundfiles will be allready copied

@Marth: manuel run worked for me, too. But if you make it with the cmd you have the complete feedback and can see what's wrong if something not works

Kingpin · Post by **Kingpin** » Sat Mar 22, 2014 3:20 pm

That worked, but now I have another problem. I munged it, and it is only 5 KB (not sure how big it should be), and I moved it to my addon/SSC/Data/_LVL_PC/SOUND, and it is still using stock music.

Marth8880 · Post by **Marth8880** » Sat Mar 22, 2014 3:50 pm

Your file is small because all you're loading in it is one sound effect. If you want new music, you're going to need a whole lot more than that.

http://www.gametoast.com/viewtopic.php? ... &sk=t&sd=a

Kingpin · Post by **Kingpin** » Sat Mar 22, 2014 4:04 pm

I followed that tutorial, but I am confused at what you are saying. All I am changing is the ambient background music, so don't I only need one file? (Music1, since it is a hero assault map)

Marth8880 · Post by **Marth8880** » Sat Mar 22, 2014 4:20 pm

Whoops. I read Anakin's post with the .asfx file and thought it was your post.

Anyways, do you have your .stm and .mus files? Have you made the necessary changes to your LUA? Could you post your .req, .stm, .snd, .mus, and .lua files please?

Sound Problems

Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems

Re: Sound Problems